Hello Guest it is March 28, 2024, 04:03:39 PM

Show Posts

This section allows you to view all posts made by this member. Note that you can only see posts made in areas you currently have access to.


Messages - andmar2005

Pages: 1 2 »
1
hi
in theory you age, but you have to determine what are you going to do with this macro
maybe there is another solution to this simpler

2
Input settings set OemTrig # 15 port and pin your signal
paste it to macropump and restart mach3


Sub Main
  If IsActive(OEMTRIG17) Then
     SetUserLED(1032, 1)
     'ActivateSignal(OUTPUT18)
  End If
Sleep (50)
End Sub

3
'simple button
'Paste the contents of the button

 If GetUserLed(1032)=1 Then
     SetUserLED(1032, 0)
     DeActivateSignal(OUTPUT17)
    End
  End If
 
  ActivateSignal(OUTPUT17)
  SetUserLED(1032, 1)

4
VB and the development of wizards / Re: CNC KNEE MILL ATC HELP!
« on: March 01, 2015, 03:47:27 PM »
macro to return the tool from the spindle to the magazine
example, of course,


'---------------------------------------------------------------------------------------------------------------
' oddanie narzędzia z wrzeciona do magazynu
' andmar2005
'---------------------------------------------------------------------------------------------------------------

Dim a, b, c

' ----------------------------------------------------------------------------

 magazyn_zbazowanie
 powietrze_C
 wrzeciono_0
   
 T_wrzeciono = GetUserLabel(9)
 pozycja_magazyn = GetUserLabel(10)
   
 If (pozycja_magazyn = T_wrzeciono) Then
    Sleep(50)
    Message("Oddaje narzędzie")
    Oddaje
    SetUserLabel(9,0)
    Sleep(50)
    End
 End If
   
 If (T_wrzeciono =0) Then
    Sleep(150)
    Message("Co mam Oddać jest T" & nowe_T)
    Sleep(150)
    End
 End If   
   
    a=GetUserLabel(10) 'pozycja magazynu
    b=GetUserLabel(9) ' T w wrzecinie
    c=20 'ilość narzędzi w magazynie
   
    x= a-b
    y= b-a
' ----------------------------------------------------------------------------

  If x<0 Then         
    z= x+c
  End If
 
  If x>0 Then         
    z= x
  End If
' ----------------------------------------------------------------------------

  If y<0 Then         
    t= y+c
  End If
 
  If y>0 Then         
    t= y
  End If
' ----------------------------------------------------------------------------

  If t>z Then ' w lewo
   W_lewo
  End If
  If t<z  Then ' w prawo
   W_prawo
  End If
' ----------------------------------------------------------------------------

  If t=z Then ' warunek specjalny poniewaz mamy parzysta wartosc narzedzi
   W_prawo
  End If
  Oddaje
End
 
' ----------------------------------------------------------------------------
'Oddaje narzędzie do magazynu
Sub Oddaje()

     Code "G53 Z4 F2000" ' pozycja wymiany narzędzia
        While IsMoving()
         Sleep(50)
        Wend
      Sleep(20)
     Code "G90"
     
     ActivateSignal(OUTPUT13) 'Magazyn w prawo
       If(Not GetUserLed(1307)) Then 'Sprawdzam czy jest w prawo
        While GetUserLed(1307) =0
        Sleep(20)
        Wend
       End If    
     DeActivateSignal(OUTPUT13)
     Sleep(20)
     ActivateSignal(OUTPUT16)'Blokada narzędzia - odblokuj
       If(Not GetUserLed(1305)) Then 'Sprawdzam czy odblokował
        While GetUserLed(1305) =0
        Sleep(20)
        Wend   
       End If
     ActivateSignal(OUTPUT15)'Magazyn w dół
       If(Not GetUserLed(1309)) Then 'Sprawdzam czy jest w dół
        While GetUserLed(1309) =0
        Sleep(20)
        Wend
       End If
     DeActivateSignal(OUTPUT16)'Blokada narzędzia - zablokuj
     Sleep(20)
     DeActivateSignal(OUTPUT15)
     Sleep(20)
     ActivateSignal(OUTPUT12)'Magazyn w lewo
       If(Not GetUserLed(1306)) Then 'Sprawdzam czy jest w lewo
        While GetUserLed(1306) =0
        Sleep(20)
        Wend
       End If
     DeActivateSignal(OUTPUT12)
     ActivateSignal(OUTPUT14)'Magazyn w góre
       If(Not GetUserLed(1308)) Then 'Sprawdzam czy jest w góre
        While GetUserLed(1308) =0
        Sleep(20)
        Wend
       End If
   DeActivateSignal(OUTPUT14)
   Sleep(20)
   Message("ODDAŁEM NARZĘDZIE T" & T_wrzeciono)
   Sleep(50)
   SetUserLabel(9,0)
   czekam_na_wykonanie
End Sub

' ----------------------------------------------------------------------------
'Magazyn obraca sie w lewo   
Sub W_lewo()
        While (Not Szukam_T)
   nrT_M = GetuserLabel(10)
                ActivateSignal(OUTPUT18)' rozładowanie kondensatora - wylączone
                Sleep(50)
                SetUserLabel(11,"L")
           ActivateSignal(OUTPUT10)
               Sleep(800)   

 If(Not GetUserLed(1301)) Then
  While   GetUserLed(1301) =1
  Sleep(10)
  Wend
 End If

DeActivateSignal(OUTPUT10) ' obroty w lewo - wyłączone
Sleep(50)
DeActivateSignal(OUTPUT18) 'rozładowanie kondensatora - wlączone
Sleep(20)
ActivateSignal(OUTPUT11)' obroty w prawo - włączone w celu wychamowania silnika
Sleep(50)
DeActivateSignal(OUTPUT11)' obroty w prawo - wyłączone

 SetUserLabel(10,(nrT_M - 1))
 Sleep(15)
 a=GetuserLabel(10)
 If a=0 Then
 SetuserLabel(10,c)
 End If

SetUserLabel(11,"")
          
          
        If(GetuserLabel(10) = T_wrzeciono) Then
          Szukam_T = true
        End If
                  Sleep(50) 
        Wend 
End Sub   
' ----------------------------------------------------------------------------
'Magazyn obraca sie w prawo
Sub W_prawo()
        While (Not Szukam_T)
   nrT_M = GetuserLabel(10)
                ActivateSignal(OUTPUT18)' rozładowanie kondensatora - wylączone
                Sleep(50)
                SetUserLabel(12,"")
           ActivateSignal(OUTPUT11)
Sleep(800)   

 If(Not GetUserLed(1301)) Then
  While   GetUserLed(1301) =1
  Sleep(10)
  Wend
 End If

DeActivateSignal(OUTPUT11) ' obroty w lewo - wyłączone
Sleep(50)
DeActivateSignal(OUTPUT18) 'rozładowanie kondensatora - wlączone
Sleep(20)
ActivateSignal(OUTPUT10)' obroty w prawo - włączone w celu wychamowania silnika
Sleep(50)
DeActivateSignal(OUTPUT10)' obroty w prawo - wyłączone

 SetUserLabel(10,(nrT_M + 1))
 Sleep(15)
 a=GetuserLabel(10)
 If a=c+1 Then
 SetuserLabel(10,1)
 End If

SetUserLabel(12,"")

          
      If(GetuserLabel(10) = T_wrzeciono) Then
        Szukam_T = true
      End If
                   Sleep(50)
          Wend
End Sub
' ----------------------------------------------------------------------------
'Sprawdzam zbazowanie magazynu   
Sub magazyn_zbazowanie()
   If GetUserLed(1032) =0 Or GetUserLabel(10) = "" Then
    okno = MsgBox("MAGAZYN BRAK ZBAZOWANIA"& Chr(10) &""& Chr(10) &">> ZBAZUJ MAGAZYN <<" ,16, "BAZOWANIE MAGAZYNU")
    Sleep(50)
    End
   End If
End Sub   
' ----------------------------------------------------------------------------
' Jesli  narzedzie to T0 w wrzecionie
Sub wrzeciono_0 ()
   If GetUserLabel(9) = 0 Then
           okno = MsgBox("CO MAM ODDAĆ "& Chr(10) &""& Chr(10) &">> WRZECIONO JEST PUSTE <<" ,16, " **** T0 **** ")
           Sleep(50)
           End
        End If
End Sub
' ----------------------------------------------------------------------------
' Jesli  brak ciśnienia powietrza
Sub powietrze_C ()
   If GetUserLed(1005) = 1 Then
           okno = MsgBox("Brak ciśnienia "& Chr(10) &""& Chr(10) &">> POWIETRZA <<" ,16, " POWIETRZE ")
           Sleep(50)
           End
        End If
End Sub         
' ----------------------------------------------------------------------------   

Sub czekam_na_wykonanie ()
   While IsMoving()
   Sleep(50)
   Wend
End Sub
'------------------------------------------------------------------------------

5
VB and the development of wizards / Re: CNC KNEE MILL ATC HELP!
« on: March 01, 2015, 02:14:37 PM »
hi
You can do as it Hurco magazine 20 tools
- Have a position sensor on the tool T20
- The engine turns 60W 200V and has a sensor that checks performed rotation of 360 degrees
the rest is just a VB macro that will look for the path to the tool change

6
Mach Screens / Re: tooltiptext
« on: February 08, 2015, 03:00:01 PM »
hi

paste button

a=GetDro(24)
sleep(100)
SetButtonText("T" &a)

7
Zobacz to
My M6start

'---------------------------------------------------------------------------------------------------------------
' Automatyczny pomiar bazy materiałowej dla osi Z
' andmar2005
'---------------------------------------------------------------------------------------------------------------
Dim obecby_posow
Dim jakie_G

Const Podkladka_pomiarowa = 41.45  '<<TU PODAJEMY WYSOKOŚĆ PODKŁADKI POMIAROWEJ
'---------------------------------
Const o_ile = 8.55 '<< Tu podajemy o ile podniesie się w osi Z nad PODKŁADKE POMIAROWA
'---------------------------------
Const droga_pomiaru = -5 ' << Tu podajemy odcinek pomiaru -w osi Z pojedzie -5mm
'---------------------------------
Const posow_pomiaru = 25 ' << Tu podajemy posów pomiaru -w osi Z pojedzie F25
'---------------------------------
Sub Program
 zbazowonie_maszyny
 sprawdzam_wrzeciono
 sprawdzam_czujnik
 odczyt_F
 odczyt_G
'---------------------------------------------------------------------------------------------------------------
'Zaczyna pomiar
    Call SetOemDro(42,0)'UWAGA ZERUJE OWSET DANEGO NARZĘDZIA !!!!
    Sleep(100)
    DoOEMButton (1010) 'Zeruje dro osi Z
    Code "G4 P2" ' odmierza czas
    Code "G90"
    Code "G31 Z" & droga_pomiaru & "F" & posow_pomiaru 'Start pomiaru - jedzie w z do styku Podkladka_pomiarowa
    czekam_na_wykonanie
    Styk_sondy = GetVar(2002) 'Przechwytuje miejsce styku do Podkladka_pomiarowa
    Code "G0 Z" &Styk_sondy 'Powraca do miejsca styku
    czekam_na_wykonanie
    przekroczenie_Z
'---------------------------------------------------------------------------------------------------------------
'Jeśli narzędzie nie przekroczyło parametru droga_pomiaru
    Call SetDro (2, Podkladka_pomiarowa) ' Wpisuje wysokość PODKŁADKI POMIAROWEJ
    Czekam_na_wykonanie
    Code "G4 P0.25" 'odmierza czas
    odczytDroZ = GetDro(2)
    Code "G1 Z" & odczytDroZ + o_ile & "F300" 'Podnosi oś Z nad PODKŁADKE POMIAROWA
    Code "(Oś Z ustawiona na zerze materiału Przykładowo G54 w osi Z)" 'info o wykonaniu pomiaru
    czekam_na_wykonanie
 End If
 wpisuje_F
 wpisuje_G
End Sub
'---------------------------------------------------------------------------------------------------------------

Sub zbazowonie_maszyny ()
If GetOEMLed(807) Or GetOEMLed(808) Or GetOEMLed(809) Then
     bazowanie = MsgBox("Maszyna nie zbazowana"& Chr(10) &""& Chr(10) &"ZBAZUJ MASZYNE" ,16, "BAZOWANIE")
     End
End If
End Sub
'---------------------------------------------------------------------------------------------------------------

Sub sprawdzam_wrzeciono () 'Sprawdza czy wrzeciono pracuje
If GetOEMLed(11) Then
wrzeciono = MsgBox("Wrzeciono ON"& Chr(10) &""& Chr(10) &"WYŁĄCZAM >> WRZECIONO OFF <<" ,48,"TEST PRACY WRZECIONA")
  If wrzeciono = 1 Then
      Code "M5"
      Sleep (500)
      Message "Wrzeciono OFF"
      Sleep (100)
      czekam_na_wykonanie
  End If
End If
End Sub
'---------------------------------------------------------------------------------------------------------------

Sub sprawdzam_czujnik ()
If GetOemLed (825)=0 Then 'Sprawdź czy sonda jest zwarta przed pomiarem
     Else
     test = MsgBox("Sprawdź czujnik"& Chr(10) &""& Chr(10) &"JEST TERAZ ZWARTY" ,32, "TEST CZUJNIKA") 'Komunikat
     End
End If
End Sub
'---------------------------------------------------------------------------------------------------------------

Sub odczyt_F ()
   obecby_posow = GetOemDRO(818) 'odczyt aktualnego F
End Sub
'---------------------------------------------------------------------------------------------------------------
Sub wpisuje_F ()
    Code "F" & obecby_posow& 'wczytuje odczytany F
End Sub
'---------------------------------------------------------------------------------------------------------------

Sub odczyt_G ()
jakie_G = GetOemLED(48) 'odczyt G90 czy G91
End Sub
'---------------------------------------------------------------------------------------------------------------
Sub wpisuje_G ()
    If jakie_G = 0 Then 'przywraca odczytany G90 lub G91
    Code "G91"
    End If
End Sub

'---------------------------------------------------------------------------------------------------------------

Sub przekroczenie_Z ()
     test_Z= GetDro(2)
     If (test_Z) <= (droga_pomiaru) Then 'Oblicza czy nie przekroczyło droga_pomiaru
       pomiar = MsgBox("BRAK SYGNAŁU Z CZUJNIKA"& Chr(10) &""& Chr(10) &">> PONOW POMIAR OSI - Z - <<" ,16, "DROGA POMIARU")
       wpisuje_F
       wpisuje_G
       End
     End If
Sub End
'---------------------------------------------------------------------------------------------------------------

Sub czekam_na_wykonanie ()
   While IsMoving()
   Sleep(50)
   Wend
End Sub
'---------------------------------------------------------------------------------------------------------------
'Koniec   

8
General Mach Discussion / Re: manual tool zero
« on: January 13, 2015, 01:27:44 AM »
Welcome

1- Work Offsets G54 in the Z axis on the material always measure tool No. 1

this script

'---------------------------------------------------------------------------------------------------------------
' Automatyczny pomiar bazy materiałowej dla osi Z
' andmar2005
'---------------------------------------------------------------------------------------------------------------
Dim Podkladka_pomiarowa
Dim o_ile
Dim droga_pomiaru
Dim posow_pomiaru
Dim obecby_posow
Dim jakie_G

Podkladka_pomiarowa = 41.45  '<<TU PODAJEMY WYSOKOŚĆ PODKŁADKI POMIAROWEJ
'---------------------------------
o_ile = 8.55 '<< Tu podajemy o ile podniesie się w osi Z nad PODKŁADKE POMIAROWA
'---------------------------------
droga_pomiaru = 5 ' << Tu podajemy odcinek pomiaru -w osi Z pojedzie -5mm
'---------------------------------
posow_pomiaru = 25 ' << Tu podajemy posów pomiaru -w osi Z pojedzie F25
'---------------------------------
obecby_posow = GetOemDRO(818) 'odczyt aktualnego parametru F
'---------------------------------
jakie_G = GetOemLED(48) 'odczy czy G90/G91

'-----------------------------------------------------------------------------------------
'Sprawdzam zbazowonie maszyny
If GetOEMLed(807) And GetOEMLed(808) And GetOEMLed(809) Then
     bazowanie = MsgBox("Maszyna nie zbazowana"& Chr(10) &""& Chr(10) &"ZBAZUJ MASZYNE" ,16, "BAZOWANIE")
     End
End If
'-----------------------------------------------------------------------------------------
'Sprawdzam wrzeciono
If GetOEMLed(11) Then
wrzeciono = MsgBox("Wrzeciono ON"& Chr(10) &""& Chr(10) &"WYŁĄCZAM >> WRZECIONO OFF <<" ,48,"TEST PRACY WRZECIONA")
  If wrzeciono = 1 Then
      Code "M5"
      Sleep (500)
      Message "Wrzeciono OFF"
      Sleep (100)
      While IsMoving () 'czeka na wykonanie pomiaru
      Wend
  End If
End If
'------------------------------------------------------------------------------------
'Sprawdzam czujnik
If GetOemLed (825)=0 Then 'Sprawdź czy sonda jest już zwarta lub uszkodzona
     Else
     test = MsgBox("Sprawdź czujnik"& Chr(10) &""& Chr(10) &"JEST TERAZ ZWARTY" ,32, "TEST CZUJNIKA") 'Komunikat
     End
End If
'------------------------------------------------------------------------------------
'Zaczyna pomiar
 DoOEMButton (1010) 'Zeruje dro osi Z i zaczyna pomiar
 Code "G4 P2" ' odmierza czas
 Code "G90"
 Code "G31 Z-" & droga_pomiaru & "F" & posow_pomiaru 'Start pomiaru - jedzie w z do styku Podkladka_pomiarowa
 While IsMoving() 'czeka
 Wend
'------------------------------------------------------------------------------------
'Sprawdza czy przekroczyło parametr droga_pomiaru
 TestZ = GetDro(2) 'Odczyt aktualnej pozycji osi Z
If (TestZ) <= (droga_pomiaru) Then 'Oblicza czy nie przekroczyło droga_pomiaru
    pomiar = MsgBox("BRAK SYGNAŁU Z CZUJNIKA"& Chr(10) &""& Chr(10) &">> PONOW POMIAR OSI - Z - <<" ,16, "DROGA POMIARU")
    Else
'------------------------------------------------------------------------------------
'Jeśli narzędzie nie przekroczyło parametru droga_pomiaru
    Call SetDro (2, Podkladka_pomiarowa) ' Wpisuje wysokość PODKŁADKI POMIAROWEJ
    While IsMoving ()'czeka
    Wend
    Code "G4 P0.25" 'odmierza czas
    odczytDroZ = GetDro(2)
    Code "G1 Z" & odczytDroZ + o_ile & "F300" 'Podnosi oś Z nad PODKŁADKE POMIAROWA
    Code "(Oś Z ustawiona na zerze materiału Przykładowo G54 w osi Z)" 'info o wykonaniu pomiaru
    While IsMoving () 'czeka
    Wend
'------------------------------------------------------------------------------------
'Przywraca F i G
        Code "F" & obecby_posow& 'Wczytuje początkowy F
       If jakie_G = 0 Then 'przywraca odczy G90 lub G91
       Code "G91"
       End If  
End If      

2 - Then degree all the tools that I use for the treatment of
For example, the tool
T01 - for the tool Height (H) in the Z-axis must be 0
T02
T09
T12
All tools (except T01 - I measured the G54) degree
this script

'---------------------------------------------------------------------------------------------------------------
' Automatyczny pomiar narzędzia
' andmar2005
'---------------------------------------------------------------------------------------------------------------
Dim Podkladka_pomiarowa
Dim o_ile
Dim droga_pomiaru
Dim posow_pomiaru
Dim narzedzie
Dim obecby_posow
Dim jakie_G
'---------------------------------------------------------------------------------------------------------------

Podkladka_pomiarowa = 41.45  '<<TU PODAJEMY WYSOKOŚĆ PODKŁADKI POMIAROWEJ
'---------------------------------
o_ile = 8.55 '<< Tu podajemy o ile podniesie się w osi Z nad PODKŁADKE POMIAROWA
'---------------------------------
droga_pomiaru = 5 ' << Tu podajemy odcinek pomiaru -w osi Z pojedzie -5mm
'---------------------------------
posow_pomiaru = 25 ' << Tu podajemy posów pomiaru -w osi Z pojedzie F25
'---------------------------------
narzedzie = GetDRO (24)' pobiera dane dla zminnej
'---------------------------------
obecby_posow = GetOemDRO(818) 'odczyt aktualnego parametru F
'---------------------------------
jakie_G = GetOemLED(48) 'odczy czy G90/G91

'---------------------------------------------------------------------------------------------------------------
'Sprawdzam czujnik
If GetOemLed (825)=0 And narzedzie>0 Then 'Sprawdza stan czujnika i nr narzędzia
  Else
    test = MsgBox("Sprawdź czujnik >> jest teraz zwarty"& Chr(10) &""& Chr(10) &"LUB NARZĘDZIE >> T0 <<" ,32, "TEST CZUJNIKA I NUMERU NARZEDZIA") 'Komunikat
  End
End If
'---------------------------------------------------------------------------------------------------------------
'Zaczyna pomiar
      Code "G4 P2" ' Czeka czas P
      Code "G90"
      Code "G31 Z-" & droga_pomiaru & "F" & posow_pomiaru 'Start pomiaru - jedzie w z do styku Podkladka_pomiarowa
      While IsMoving() 'czeka na wykonanie pomiaru (pętli)
      Wend
'------------------------------------------------------------------------------------
'Jeśli narzędzie dotkneło PODKŁADKI POMIAROWEJ
    If narzedzie <>0 Then
       Z_Offset = GetOEMDRO ( 49 ) 'pobiera dane
       Axis_Pos = GetOEMDRO(85) 'pobiera dane  
       Tool_Offset = Axis_Pos - Z_Offset - Podkladka_pomiarowa 'Oblicza owset
     Call setOEMDRO(42, Tool_Offset) ' Wpisuje wyliczony owset
       wpis = MsgBox("WPISANO OWSET NARZĘDZIA"& Chr(10) &""& Chr(10) &">>  T " & narzedzie &" <<" ,64, "OWSET NARZEDZIA")'Komunikat
       Code "G01 Z" & (Podkladka_pomiarowa + o_ile) & "F300" ' podnosi oś Z na 50
    End If
'------------------------------------------------------------------------------------
'Przywraca F i G
    Code "F" & obecby_posow& 'Wczytuje początkowy F
       If jakie_G = 0 Then 'przywraca odczy G90 lub G91
       Code "G91"
       End If
        

All measured - start to work

Best Regards

9
General Mach Discussion / Re: manual tool zero
« on: January 10, 2015, 05:35:45 PM »
'---------------------------------------------------------------------------------------------------------------
' Automatyczny pomiar bazy materiałowej dla osi Z
' andmar2005
'---------------------------------------------------------------------------------------------------------------

Podkladka_pomiarowa = 41.45  '<<TU PODAJEMY WYSOKOŚĆ PODKŁADKI POMIAROWEJ

o_ile = 8.55 '<< Tu podajemy o ile podniesie się w osi Z nad PODKŁADKE POMIAROWA

droga_pomiaru = 5 ' << Tu podajemy odcinek pomiaru -w osi Z pojedzie -5mm

posow_pomiaru = 25 ' << Tu podajemy posów pomiaru -w osi Z pojedzie F25

'-----------------------------------------------------------------------------------------
'Sprawdzam wrzeciono
If GetOEMLed(11) Then
wrzeciono = MsgBox("Wrzeciono ON"& Chr(10) &""& Chr(10) &"WYŁĄCZAM >> WRZECIONO OFF <<")
  If wrzeciono = 1 Then
      Code "M5"
      Sleep (500)
      Message "Wrzeciono OFF"
      Sleep (100)
      While IsMoving () 'czeka na wykonanie pomiaru
      Wend
  End If
End If
'Koniec
'-----------------------------------------------------------------------------------------
'Sprawdzam zbazowonie maszyny
If GetOEMLed(807) And GetOEMLed(808) And GetOEMLed(809) Then
     MsgBox("Maszyna nie zbazowana"& Chr(10) &""& Chr(10) &"ZBAZUJ MASZYNE")
     End
End If
'Koniec
'------------------------------------------------------------------------------------
'Sprawdzam czujnik
If GetOemLed (825)=0 Then 'Sprawdź czy sonda jest już zwarta lub uszkodzona
     Else
     MsgBox("Sprawdź czujnik >> jest teraz zwarty") 'komunikat jesli jest zwarty
End If
'Koniec
'------------------------------------------------------------------------------------
'Zaczyna pomiar
 DoOEMButton (1010) 'Zeruje dro osi Z i zaczyna pomiar
 Code "G4 P2" ' odmierza czas
 Code "G31 Z-" & droga_pomiaru & "F" & posow_pomiaru 'Start pomiaru - jedzie w z do styku Podkladka_pomiarowa
 While IsMoving() 'czeka
 Wend
'------------------------------------------------------------------------------------
'Sprawdza czy przekroczyło parametr droga_pomiaru
 TestZ = GetDro(2) 'Odczyt aktualnej pozycji osi Z
If (TestZ) <= (droga_pomiaru) Then 'Oblicza czy nie przekroczyło droga_pomiaru
    MsgBox("BRAK SYGNAŁU Z CZUJNIKA"& Chr(10) &""& Chr(10) &">> PONOW POMIAR OSI - Z - <<")
    Else
'Koniec
'------------------------------------------------------------------------------------
'Jeśli narzędzie nie przekroczyło parametru droga_pomiaru
    Call SetDro (2, Podkladka_pomiarowa) ' Wpisuje wysokość PODKŁADKI POMIAROWEJ
    While IsMoving ()'czeka
    Wend
    Code "G4 P0.25" 'odmierza czas
    odczytDroZ = GetDro(2)
    Code "G1 Z" & odczytDroZ + o_ile & "F300" 'Podnosi oś Z nad PODKŁADKE POMIAROWA
    Code "(Oś Z ustawiona na zerze materiału Przykładowo G54 w osi Z)" 'info o wykonaniu pomiaru
    While IsMoving () 'czeka
    Wend
'Koniec
End If


10
VB and the development of wizards / Re: Infinite Loop
« on: January 03, 2015, 08:30:13 AM »
Hi


%
g01 X0 F8000
X200
X-200
G04 P200
M47 (powtarza program bez przerwy)
%

Pages: 1 2 »